home *** CD-ROM | disk | FTP | other *** search
/ Programmer Power Tools / Programmer Power Tools.iso / progjrn / pj_6_2.arc / ONGRAF62.L2 < prev    next >
Encoding:
Text File  |  1988-02-18  |  6.4 KB  |  332 lines
  1. Code from "Yet Another VGA Write Mode" by Michael Abrash, PJ,
  2. Volume 6.2.  Copyright 1987 Michael Abrash. 
  3. ; 
  4. ; *** Listing 2 ***
  5. ; 
  6. ; Program to illustrate one use of write mode 2 of the VGA and EGA by 
  7. ; drawing lines in color patterns.  
  8. ; 
  9. ; Assembled with MASM 5.0, linked with MS-LINK 3.60.  
  10. ; 
  11. ; By Michael Abrash 11/8/87 
  12. ; Stack segment para stack 'STACK'
  13.             db    512 dup(0)
  14. Stack    ends
  15.  
  16. SCREEN_WIDTH_IN_BYTES    equ    80
  17. GRAPHICS_SEGMENT equ    0a000h    ;mode 10 bit-map segment
  18. SC_INDEX    equ    3c4h    ;Sequence Controller Index register
  19. MAP_MASK    equ    2    ;index of Map Mask register
  20. GC_INDEX    equ    03ceh    ;Graphics Controller Index reg
  21. GRAPHICS_MODE    equ    5    ;index of Graphics Mode reg
  22. BIT_MASK    equ    8    ;index of Bit Mask reg
  23.  
  24. Data    segment    para common 'DATA'
  25. Pattern0    db    16
  26.         db    0, 1, 2, 3, 4, 5, 6, 7, 8
  27.         db    9, 10, 11, 12, 13, 14, 15
  28. Pattern1    db    6
  29.         db    2, 2, 2, 10, 10, 10
  30. Pattern2    db    8
  31.         db    15, 15, 15, 0, 0, 15, 0, 0
  32. Pattern3    db    9
  33.         db    1, 1, 1, 2, 2, 2, 4, 4, 4
  34. Data    ends
  35.  
  36. Code    segment    para public 'CODE'
  37.     assume    cs:Code, ds:Data
  38. Start    proc    near
  39.     mov    ax,Data
  40.     mov    ds,ax
  41.     mov    ax,10h
  42.     int    10h        ;select video mode 10h (640x350)
  43. ;
  44. ; Draw 8 radial lines in upper left quadrant in pattern 0.
  45. ;
  46.     mov    bx,0
  47.     mov    cx,0
  48.     mov    si,offset Pattern0
  49.     call    QuadrantUp
  50. ;
  51. ; Draw 8 radial lines in upper right quadrant in pattern 1.
  52. ;
  53.     mov    bx,320
  54.     mov    cx,0
  55.     mov    si,offset Pattern1
  56.     call    QuadrantUp
  57. ;
  58. ; Draw 8 radial lines in lower left quadrant in pattern 2.
  59. ;
  60.     mov    bx,0
  61.     mov    cx,175
  62.     mov    si,offset Pattern2
  63.     call    QuadrantUp
  64. ;
  65. ; Draw 8 radial lines in lower right quadrant in pattern 3.
  66. ;
  67.     mov    bx,320
  68.     mov    cx,175
  69.     mov    si,offset Pattern3
  70.     call    QuadrantUp
  71. ;
  72. ; Wait for a key before returning to text mode and ending.
  73. ;
  74.     mov    ah,01h
  75.     int    21h
  76.     mov    ax,03h
  77.     int    10h
  78.     mov    ah,4ch
  79.     int    21h
  80. ;
  81. ; Draws 8 radial lines with specified pattern in specified mode 10h
  82. ; quadrant.
  83. ;
  84. ; Input:
  85. ;    BX = X coordinate of upper left corner of quadrant
  86. ;    CX = Y coordinate of upper left corner of quadrant
  87. ;    SI = pointer to pattern, in following form:
  88. ;        Byte 0: Length of pattern
  89. ;        Byte 1: Start of pattern, one color per byte
  90. ;
  91. ; AX, BX, CX, DX destroyed
  92. ;
  93. QuadrantUp    proc    near
  94.     add    bx,160
  95.     add    cx,87        ;point to the center of the quadrant
  96.     mov    ax,0
  97.     mov    dx,160
  98.     call    LineUp        ;draw horizontal line to right edge
  99.     mov    ax,1
  100.     mov    dx,88
  101.     call    LineUp        ;draw diagonal line to upper right
  102.     mov    ax,2
  103.     mov    dx,88
  104.     call    LineUp        ;draw vertical line to top edge
  105.     mov    ax,3
  106.     mov    dx,88
  107.     call    LineUp        ;draw diagonal line to upper left
  108.     mov    ax,4
  109.     mov    dx,161
  110.     call    LineUp        ;draw horizontal line to left edge
  111.     mov    ax,5
  112.     mov    dx,88
  113.     call    LineUp        ;draw diagonal line to lower left
  114.     mov    ax,6
  115.     mov    dx,88
  116.     call    LineUp        ;draw vertical line to bottom edge
  117.     mov    ax,7
  118.     mov    dx,88
  119.     call    LineUp        ;draw diagonal line to bottom right
  120.     ret
  121. QuadrantUp    endp
  122. ;
  123. ; Draws a horizontal, vertical, or diagonal line (one of the eight
  124. ; possible radial lines) of the specified length from the specified
  125. ; starting point.
  126. ;
  127. ; Input:
  128. ;    AX = line direction, as follows:
  129. ;        3  2  1
  130. ;        4  *  0
  131. ;        5  6  7
  132. ;    BX = X coordinate of starting point
  133. ;    CX = Y coordinate of starting point
  134. ;    DX = length of line (number of pixels drawn)
  135. ;
  136. ; All registers preserved.
  137. ;
  138. ; Table of vectors to routines for each of the 8 possible lines.
  139. ;
  140. LineUpVectors    label    word
  141.     dw    LineUp0, LineUp1, LineUp2, LineUp3
  142.     dw    LineUp4, LineUp5, LineUp6, LineUp7
  143.  
  144. ;
  145. ; Macro to draw horizontal, vertical, or diagonal line.
  146. ;
  147. ; Input:
  148. ;    XParm = 1 to draw right, -1 to draw left, 0 to not move horz.
  149. ;    YParm = 1 to draw up, -1 to draw down, 0 to not move vert.
  150. ;    BX = X start location
  151. ;    CX = Y start location
  152. ;    DX = number of pixels to draw
  153. ;    DS:SI = line pattern
  154. ;
  155. MLineUp    macro    XParm, YParm
  156.     local    LineUpLoop, CheckMoreLine
  157.     mov    di,si        ;set aside start offset of pattern
  158.     lodsb            ;get length of pattern
  159.     mov    ah,al
  160.  
  161. LineUpLoop:
  162.     lodsb            ;get color of this pixel...
  163.     call    DotUpInColor    ;...and draw it
  164. if XParm EQ 1
  165.     inc    bx
  166. endif
  167. if XParm EQ -1
  168.     dec    bx
  169. endif
  170. if YParm EQ 1
  171.     inc    cx
  172. endif
  173. if YParm EQ -1
  174.     dec    cx
  175. endif
  176.     dec    ah        ;at end of pattern?
  177.     jnz    CheckMoreLine
  178.     mov    si,di        ;get back start of pattern
  179.     lodsb
  180.     mov    ah,al        ;reset pattern count
  181.  
  182. CheckMoreLine:
  183.     dec    dx
  184.     jnz    LineUpLoop
  185.     jmp    LineUpEnd
  186.     endm
  187.  
  188. LineUp    proc    near
  189.     push    ax
  190.     push    bx
  191.     push    cx
  192.     push    dx
  193.     push    si
  194.     push    di
  195.     push    es
  196.  
  197.     mov    di,ax
  198.  
  199.     mov    ax,GRAPHICS_SEGMENT
  200.     mov    es,ax
  201.  
  202.     push    dx        ;save line length
  203. ;
  204. ; Enable writes to all planes.
  205. ;
  206.     mov    dx,SC_INDEX
  207.     mov    al,MAP_MASK
  208.     out    dx,al
  209.     inc    dx
  210.     mov    al,0fh
  211.     out    dx,al
  212. ;
  213. ; Select write mode 2.
  214. ;
  215.     mov    dx,GC_INDEX
  216.     mov    al,GRAPHICS_MODE
  217.     out    dx,al
  218.     inc    dx
  219.     mov    al,02h
  220.     out    dx,al
  221. ;
  222. ; Vector to proper routine.
  223. ;
  224.     pop    dx        ;get back line length
  225.  
  226.     shl    di,1
  227.     jmp    cs:[LineUpVectors+di]
  228. ;
  229. ; Horizontal line to right.
  230. ;
  231. LineUp0:
  232.     MLineUp    1, 0
  233. ;
  234. ; Diagonal line to upper right.
  235. ;
  236. LineUp1:
  237.     MLineUp    1, -1
  238. ;
  239. ; Vertical line to top.
  240. ;
  241. LineUp2:
  242.     MLineUp    0, -1
  243. ;
  244. ; Diagonal line to upper left.
  245. ;
  246. LineUp3:
  247.     MLineUp    -1, -1
  248. ;
  249. ; Horizontal line to left.
  250. ;
  251. LineUp4:
  252.     MLineUp    -1, 0
  253. ;
  254. ; Diagonal line to bottom left.
  255. ;
  256. LineUp5:
  257.     MLineUp    -1, 1
  258. ;
  259. ; Vertical line to bottom.
  260. ;
  261. LineUp6:
  262.     MLineUp    0, 1
  263. ;
  264. ; Diagonal line to bottom right.
  265. ;
  266. LineUp7:
  267.     MLineUp    1, 1
  268.  
  269. LineUpEnd:
  270.     pop    es
  271.     pop    di
  272.     pop    si
  273.     pop    dx
  274.     pop    cx
  275.     pop    bx
  276.     pop    ax
  277.     ret
  278. LineUp    endp
  279. ;
  280. ; Draws a dot in the specified color at the specified location.
  281. ; Assumes that the VGA is in write mode 2 with writes to all planes
  282. ; enabled and that ES points to display memory.
  283. ;
  284. ; Input:
  285. ;    AL = dot color
  286. ;    BX = X coordinate of dot
  287. ;    CX = Y coordinate of dot
  288. ;    ES = display memory segment
  289. ;
  290. ; All registers preserved.
  291. ;
  292. DotUpInColor    proc    near
  293.     push    bx
  294.     push    cx
  295.     push    dx
  296.     push    di
  297. ;
  298. ; Point ES:DI to the display memory byte in which the pixel goes, with
  299. ; the bit mask set up to access that pixel within the addressed byte.
  300. ;
  301.     push    ax        ;preserve dot color
  302.     mov    ax,SCREEN_WIDTH_IN_BYTES    
  303.     mul    cx        ;offset of start of top scan line
  304.     mov    di,ax
  305.     mov    cl,bl
  306.     and    cl,111b
  307.     mov    dx,GC_INDEX
  308.     mov    al,BIT_MASK
  309.     out    dx,al
  310.     inc    dx
  311.     mov    al,80h
  312.     shr    al,cl
  313.     out    dx,al        ;set the bit mask for the pixel
  314.     shr    bx,1
  315.     shr    bx,1
  316.     shr    bx,1        ;X in bytes
  317.     add    di,bx        ;offset of byte pixel is in
  318.     mov    al,es:[di]    ;load latches
  319.     pop    ax        ;get back dot color
  320.     stosb            ;write dot in desired color
  321.  
  322.     pop    di
  323.     pop    dx
  324.     pop    cx
  325.     pop    bx
  326.     ret
  327. DotUpInColor    endp
  328. Start    endp
  329. Code    ends
  330.     end    Start
  331.  
  332.